// POVRAY ||| COURS N¡1 06/11/2006

// BIBLIOTHEQUE
#macro ma_texture( toto )
	texture								// mati�re
	{	pigment { color rgbt toto }	// couleur rŽflŽchie
		finish							//
		{	ambient 0.2					// rŽflexion lumi�re ambiante
			diffuse 0.7					// rŽflexion lumi�res incidentes
			specular 0.7				// rŽflexion points lumineux
			roughness 0.01				// rugositŽ / brillance
			reflection 0.1				// 
		}
	}	
#end

#macro un_tore( rayon_1, rayon_2, couleur, translation, rotation )
	object 
	{	torus { 	rayon_1, rayon_2 }
		translate 	translation
		rotate 		rotation
		ma_texture( couleur )
	}
#end

#macro multi_tores( N )
	#local i=0;
	#while (i<N)	
		un_tore( 0.2, 0.05, <i/(N-1),1-i/(N-1),0>, <0.5,0,0>, <90, 360*i/N ,0> )
	#local i=i+1;
	#end
#end

#macro anneau()
	difference
	{	un_tore( 0.5, 0.2, 	<0,0,0,0.0>, <0,0,0>, <0,0,0> )
		multi_tores( 12 )
	}
#end

#macro chainon()
	anneau()
	object
	{	anneau()
		translate <0.5,0,0>
		rotate <90,0,0>
	}
#end

#macro axes ( longueur )
	object { cylinder { <-longueur,0,0>, <longueur,0,0>, 0.01 } pigment { color rgb <1,0,0> } }
	object { cylinder { <0,-longueur,0>, <0,longueur,0>, 0.01 } pigment { color rgb <0,1,0> } }
	object { cylinder { <0,0,-longueur>, <0,0,longueur>, 0.01 } pigment { color rgb <0,0,1> } }
#end

#macro boite()
	object
	{	box { -1/2, 1/2 }
		pigment { color rgbt <1,1,1,0.7> }
	}
#end

#macro cubix( N )
	union
	{
		#local k=0;	#while (k<N)
		#local j=0;	#while (j<N)
		#local i=0; #while (i<N)				
			#local ii = i/(N-1);	#local uu = -0.5*(1-ii)+0.5*ii;		
			#local jj = j/(N-1);	#local vv = -0.5*(1-jj)+0.5*jj;		
			#local kk = k/(N-1);	#local ww = -0.5*(1-kk)+0.5*kk;	
			#if ( i!=j & j!=k & k!=i )
				object 	{ 	sphere { <uu,vv,ww>, 1/(2*(N-1)) } ma_texture( <ii,jj,kk,0.9> ) interior { ior  1.2 } }
			#end
		#local i=i+1; #end
		#local j=j+1; #end
		#local k=k+1; #end
	}
#end

// SCENE
camera { location <-0.8,1,-1> look_at <0,0,0> }
background { color rgb 1/2 }
light_source { <-1,1,-1> color rgb <1,1,1> } 
light_source { <1,1,-1> color rgb <1,1,1> } 
light_source { <0,1,5> color rgb <1,1,1> } 

axes( 1 )
//chainon()
//boite()
cubix( 4 )

/*
intersection
{	cubix (5)
	object { box { -1/2, 1/2 } pigment { color rgb <1,1,1,1.0> } rotate <-15,-15,0> }
}
¬*/